awk
— хороший инструмент для этого. Существует отличный учебник поawk
:Awk -A Tutorial and Introduction -Брюса Барнетта -Grymoire
Попробуйте это:
awk '
{
columns[$3]=1 ; ids[$2]=1 ; col1[$2 ":::" $3]=$1
if (maxcollen< length($1)) maxcollen=length($1)
if (maxcollen< length($2)) maxcollen=length($2)
if (maxcollen< length($3)) maxcollen=length($3)
}
END {
printf("%-" maxcollen "s ", "")
for (key in columns) {
printf("%-" maxcollen "s ",key)
}
for (id in ids) {
printf("\n%-" maxcollen "s ", id)
for (key in columns) {
printf("%-" maxcollen "s ", col1[id ":::" key])
}
}
printf("\n")
}' myfile.csv
Выход:
glkgb tzfl mv abcdef xyz
id3 2 5
id100 4 1 2 1 8
id1 1 2 1 8
id2 1 1 6
Другая версия для отображения столбцов и идентификаторов в порядке появления:
awk '
{
if (colname[$3]!=1) {colname[$3]=1 ; cols[++coln]=$3 }
if (idval[$2]!=1) {idval[$2]=1 ; ids[++idn]=$2 }
col1[$2 ":::" $3]=$1
if (maxcollen< length($1)) maxcollen=length($1)
if (maxcollen< length($2)) maxcollen=length($2)
if (maxcollen< length($3)) maxcollen=length($3)
}
END {
printf("%-" maxcollen "s ", "")
for (i=1; i<=coln ; i++ ) {
printf("%-" maxcollen "s ",cols[i])
}
for (j=1; j<=idn ; j++) {
printf("\n%-" maxcollen "s ", ids[j])
for (i=1; i<=coln ; i++) {
printf("%-" maxcollen "s ", col1[ids[j] ":::" cols[i]])
}
}
printf("\n")
}' myfile.csv
Выход:
xyz abcdef mv tzfl glkgb
id1 8 1 2 1
id2 6 1 1
id3 5 2
id100 8 1 2 1 4