Использование systemd для предотвращения сбоев сценариев python

Взяв за основу код Брюса, вот более эффективная реализация которая не хранит все данные в памяти.  Как указано в вопросе, предполагается, что входной файл имеет (по крайней мере) одно число в строке.  Он подсчитывает строки во входном файле, которые содержат определяющее число и передает это количество команде awk вместе с (предшествующими) отсортированными данными.  Так, например, если файл содержит

6.0
4.2
8.3
9.5
1.7

то на вход команды awk фактически поступает

5
1.7
4.2
6.0
8.3
9.5

Тогда сценарий awk фиксирует счетчик данных в блоке кода NR==1 и сохраняет среднее значение (или два средних значения, которые усредняются для получения медианы) когда видит их.

FILENAME="Salaries.csv"

(awk 'BEGIN {c=0} $1 ~ /^[-0-9]*(\.[0-9]*)?$/ {c=c+1;} END {print c;}' "$FILENAME"; \
        sort -n "$FILENAME") | awk '
  BEGIN {
    c = 0
    sum = 0
    med1_loc = 0
    med2_loc = 0
    med1_val = 0
    med2_val = 0
    min = 0
    max = 0
  }

  NR==1 {
    LINES = $1
    # We check whether numlines is even or odd so that we keep only
    # the locations in the array where the median might be.
    if (LINES%2==0) {med1_loc = LINES/2-1; med2_loc = med1_loc+1;}
    if (LINES%2!=0) {med1_loc = med2_loc = (LINES-1)/2;}
  }

  $1 ~ /^[-0-9]*(\.[0-9]*)?$/  &&  NR!=1 {
    # setting min value
    if (c==0) {min = $1;}
    # middle two values in array
    if (c==med1_loc) {med1_val = $1;}
    if (c==med2_loc) {med2_val = $1;}
    c++
    sum += $1
    max = $1
  }
  END {
    ave = sum / c
    median = (med1_val + med2_val ) / 2
    print "sum:" sum
    print "count:" c
    print "mean:" ave
    print "median:" median
    print "min:" min
    print "max:" max
  }
'