поиск и раскрашивание строк с помощью awk или другого метода

Всякий раз, когда вы обнаруживаете, что используете $'{...}'вокруг awk-скрипта, вы делаете что-то не так и должны обратиться за помощью. Никогда не делайте этого, так как это никогда не требуется в хорошо -написанном сценарии и делает ваш сценарий уязвимым, поскольку он предлагает оболочке интерпретировать некоторые его части еще до того, как awk их увидит.

Некоторые люди, столкнувшись с проблемой, думают: «Я знаю, я буду использовать регулярные выражения». Теперь у них две проблемы.:-)

Вы избегаете метасимволов регулярных выражений, чтобы регулярное выражение действовало как строка. Не делайте этого -просто используйте строку вместо операторов регулярных выражений, когда вы хотите сопоставить строку:

awk 'index($0,"DEBUG StateMachine|entr \047NTP:nextGetTimeTimeoutState\047") {
    $0 = "\033[1;41m" $0 "\033[0m"
}
1' LOG.log

\047вместо ', потому что вы не можете экранировать 'в строке с разделителями'-(, включая скрипты )в оболочке. См. http://awk.freeshell.org/PrintASingleQuote.

Чтобы выделить 2 разные линии одним цветом, вы можете использовать:

awk '
    index($0,"DEBUG StateMachine|entr \047NTP:nextGetTimeTimeoutState\047") ||
    index($0,"DEBUG StateMachine|exit \047NTP:nextGetTimeTimeoutState\047") {
        $0 = "\033[1;41m" $0 "\033[0m"
    }
1' LOG.log

и выделить 2 строки двумя разными цветами:

awk '
    index($0,"DEBUG StateMachine|entr \047NTP:nextGetTimeTimeoutState\047") {
        $0 = "\033[1;42m" $0 "\033[0m"
    }
    index($0,"DEBUG StateMachine|exit \047NTP:nextGetTimeTimeoutState\047") {
        $0 = "\033[1;41m" $0 "\033[0m"
    }
1' LOG.log

Сказав это, поскольку вы, очевидно, пытаетесь использовать разные цвета на основе разных частей ввода, теперь было бы уместно использовать регулярное выражение с группами захвата, чтобы изолировать соответствующие части ввода, а затем просто посмотреть на эти части. части, чтобы определить цвет, который будет использоваться для каждой строки, и вот как я бы реализовал это, используя GNU awk для третьего аргумента, чтобы соответствовать ()для групп захвата:

$ cat tst.awk
BEGIN {
    red    = "\033[1;41m"
    green  = "\033[1;42m"
    yellow = "\033[1;43m"
    blue   = "\033[1;44m"
    purple = "\033[1;45m"
    reset  = "\033[0m"

    map["nextGetTimeTimeoutState","entr"] = green
    map["nextGetTimeTimeoutState","exit"] = red
    map["nextIteratorState","entr"]       = yellow
    map["nextIteratorState","task"]       = blue
    map["nextIteratorState","exit"]       = purple
}
match($0,/(DEBUG|INFO) StateMachine\|(\S+)\s+\047NTP:([^\047]+)\047/,a) {
    key = a[3] SUBSEP a[2]
    if ( key in map ) {
        $0 = map[key] $0 reset
    }
}
{ print }

или используя любой POSIX awk:

$ cat tst.awk
BEGIN {
    red    = "\033[1;41m"
    green  = "\033[1;42m"
    yellow = "\033[1;43m"
    blue   = "\033[1;44m"
    purple = "\033[1;45m"
    reset  = "\033[0m"

    map["nextGetTimeTimeoutState","entr"] = green
    map["nextGetTimeTimeoutState","exit"] = red
    map["nextIteratorState","entr"]       = yellow
    map["nextIteratorState","task"]       = blue
    map["nextIteratorState","exit"]       = purple
}
match($0,/(DEBUG|INFO) StateMachine\|[^[:space:]]+[[:space:]]+\047NTP:[^\047]+\047/) {
    split($0,a,/[|[:space:]:\047]+/)
    key = a[9] SUBSEP a[7]
    if ( key in map ) {
        $0 = map[key] $0 reset
    }
}
{ print }

Какой бы из них вы ни использовали, вывод будет:

Вам не нужны промежуточные переменные red, greenи т. д., как можно было бы просто:

    map["nextGetTimeTimeoutState"]["entr"] = "\033[1;42m"
    map["nextGetTimeTimeoutState"]["exit"] = "\033[1;41m"

, но я считаю, что они помогают ясности и упрощают дальнейшее обслуживание/обновления.