Можно ли эффективно вставить слова в этих строках bash в таблицу sqlite?

Линейный инструмент sqlite3команда -не поддерживает подготовленные операторы , поэтому любая попытка сделать это в сценарии оболочки приведет к проблемам с un -экранированными кавычками и подобно. Работа с переменными в кавычках и без кавычек уже вызывает некоторую головную боль в shell/bash, и эта боль только усугубляется, когда вы работаете с базой данных SQL, которая имеет свои собственные требования к заключению в кавычки.

Подобные задачи следует выполнять на языке с библиотекой SQLite. Наиболее часто используемые языки, как компилируемые, так и интерпретируемые, имеют такие библиотеки.

Вот несколько примеров того, как это сделать в Perl:

Все эти примеры требуют установки библиотечных модулей DBI и DBD ::SQLite . Если вы используете какой-либо дистрибутив Linux, они почти наверняка будут доступны в виде пакетов. Например, в Debian запустите sudo apt install libdbd-sqlite3-perl, чтобы установить их оба. Большинство других языков будут иметь аналогичные библиотеки.

Кстати, еще одна причина отказа от использования sh или bash (или других оболочек )заключается в том, чтобы избежать боли, связанной с кавычками и разделением слов -и связанными с ними проблемами, которые существуют в сценариях оболочки, но не в других языках. (у них есть свои проблемы и причуды ).

С двумя массивами, @firstи@last:

#!/usr/bin/perl

use strict;
use DBI;

my $dbfile= './people.db';
my $dbh = DBI->connect("dbi:SQLite:dbname=$dbfile");

my @first = qw(John Paul George Ringo);
my @last = qw(Lennon McCartney Harrison Starr);

$dbh->do('CREATE TABLE IF NOT EXISTS people(fname TEXT, lname TEXT)');

my $sth = $dbh->prepare('INSERT INTO people (fname, lname) VALUES (?,?)');

for my $i (0..$#first) {
  $sth->execute($first[$i],$last[$i]);
};

Здесь важно то, что, поскольку я использовал подготовленный оператор, мне не нужно заботиться о каких-либо раздражающих символах, таких как кавычки, в любом из имен, и мне не нужно предпринимать никаких специальных действий для обработки с ними. Подготовленный оператор заставляет все это обрабатываться автоматически.

Сохраните это как, например, sql-arrays.plи сделайте его исполняемым с помощью chmod +x sql-arrays.pl.

Вы можете проверить правильность вставки записей из оболочки:

$ sqlite3 people.db -cmd ".mode column" "SELECT * FROM people;"
fname   lname    
------  ---------
John    Lennon   
Paul    McCartney
George  Harrison 
Ringo   Starr    

Конечно, вы можете написать Perl-скрипт для запуска оператора SELECT и вывода записей в любом удобном для вас формате. Я оставлю это в качестве упражнения для читателя.

С ассоциативным массивом (или хешем ),%people:

#!/usr/bin/perl

use strict;
use DBI;

my $dbfile= './people.db';
my $dbh = DBI->connect("dbi:SQLite:dbname=$dbfile");

my %people = (
  'John'   => 'Lennon',
  'Paul'   => 'McCartney',
  'George' => 'Harrison',
  'Ringo'  => 'Starr',
);

$dbh->do("CREATE TABLE IF NOT EXISTS people(fname TEXT, lname TEXT);");

my $sth = $dbh->prepare('INSERT INTO people (fname, lname) VALUES (?,?)');

for my $person (keys %people) {
  $sth->execute($person,$people{$person});
};

ПРИМЕЧАНИЕ Хеши :хранятся в произвольном порядке, поэтому записи будут вставлены в базу данных в полу-случайном порядке. Вы можете использовать sort keys %peopleвместо keys %people, но это будет вставлять записи в отсортированном порядке (Джордж, Джон, Пол, Ринго ), который не совпадает с порядком, указанным (Джон, Пол.,Джордж,Ринго ).

В большинстве случаев при работе с хэшами порядок не важен. Когда это так, обычно используют отдельный индексированный массив для хранения требуемого порядка и перебирают его вместо полу--случайных хеш-ключей.

напр. @order=qw(John Paul George Ringo);и позже for my $person (@order) {... };вместо for my $person (keys %people) {... }.

Во всяком случае, вы можете видеть, что порядок записей в БД отличается от первой версии:

$ rm -f people.db
$./sql-hash.pl
$ sqlite3 people.db -cmd ".mode column" "SELECT * FROM people;"
fname   lname    
------  ---------
John    Lennon   
Ringo   Starr    
George  Harrison 
Paul    McCartney

Стоит также отметить, что это довольно надуманный пример, -хеш-ключ должен быть уникальным , а имена далеко не таковы. Несмотря на то, что этот пример хорошо демонстрирует основную идею выборочных данных, в реальном мире хеш-ключ будет представлять собой UUID, неповторяющуюся последовательность -или какой-либо другой уникальный идентификатор, а соответствующее поле в базе данных будет быть ПЕРВИЧНЫМ КЛЮЧОМ.

Что еще более важно, при выполнении запроса SELECT модуль DBI может возвращать совпадающие строки в виде хэша или ссылки на хэш, и вы можете перебирать ключи для вывода и/или обработки данных.

Кстати, bashтакже имеет ассоциативные массивы, а также индексированные массивы. Как и ksh, zsh и awk. Большинство других языков имеют ту или иную форму ассоциативного массива или кортежей или подобных.

С массивом строк, содержащих полные имена,@people:

#!/usr/bin/perl

use strict;
use DBI;

my $dbfile= './people.db';
my $dbh = DBI->connect("dbi:SQLite:dbname=$dbfile");

my @people = ('John Lennon', 'Paul McCartney', 'George Harrison', 'Ringo Starr');

$dbh->do("CREATE TABLE IF NOT EXISTS people(fname TEXT, lname TEXT);");

my $sth = $dbh->prepare('INSERT INTO people (fname, lname) VALUES (?,?)');

foreach (@people) {
  my ($first,$last) = split;
  $sth->execute($first,$last);
};

В этой версии каждое полное имя разбивается на имя и фамилию, а затем вставляется в базу данных.

Эта форма особенно полезна, если вы хотите прочитать список имен из текстового файла (по одному имени в строке )вместо использования жесткого -закодированного массива строк.

Ни один из приведенных выше сценариев не может работать с людьми, у которых есть отчества или титулы, такие как мистер или доктор, или с теми, чьи правила именования не такие, как в большинстве англоязычных -стран мира. Приложив достаточные усилия, вы можете заставить их изменить свои имена в соответствии с вашей программой, но, вероятно, проще просто изменить алгоритм (и структуру базы данных ), чтобы справляться с такими реальными -мировыми неприятностями. Люди могут быть такими неудобными. Особенно звезды эстрады.