Извлечение блоков и значений серверов из конфигурации Nginx

Так как вы можете иметь более одного значения, разделенного пробелом -в строке, использование awkнемного сложно. Это абсолютно возможно в awk, но проще вместо этого использовать что-то вроде Perl:

$ perl -lne '
    if(/(^| )server / || eof){ 
        print join " ",@ll if $ll[0]; 
        @ll=(); 
    }
    /^(listen|root|server_name)\s+(\S[^;]+)/ && push @ll,$2' file 
80 domain1.com www.domain1.com html
80 domain2.com www.domain2.com /var/www/virtual/big.server.com/htdocs

-lneозначает «прочитать входной файл построчно (-n), удалить завершающие символы новой строки и добавить новую строку к каждому printвызову(-l)и запустить сценарий, заданный -eв каждой строке».

Код:

• if(/(^| )server / || eof){ :этот раздел запустится, если текущая строка содержит слово server, окруженное пробелами, или в начале строки.

• print join " ",@ll if $ll[0]; :если в настоящее время что-то хранится в массиве@ll(поэтому, если первый элемент массива, $ll[0], определен ), выведите содержимое массива, соединенного пробелом.

• @ll=(); :очистить массив, чтобы мы могли получить информацию о следующем сервере.

• /^(listen|root|server_name)\s+(\S[^;]+)/ && push @ll,$2':если эта строка начинается с одного из ключевых слов, а затем содержит один или несколько пробельных символов, найдите первый не -пробельный символ и как можно больше не-;символов до конца строки и добавьте этот (круглые скобки зафиксируют шаблон, так что «это» теперь$2)в массив @llдля печати.

А вот (уродливый )способ сделать это в awk:

$ awk '
    (/ server\s*\{/){ 
        if(out){
            print out
        }
        out=""
    } 
    ($1=="listen" || $1=="root" || $1=="server_name"){
        gsub(";",""); 
        $1=""; 
        gsub(/^ */,""); 
        out ? out=out" "$0 : out=$0
    }
    END{print out}' file 
80 domain1.com www.domain1.com html
80 domain2.com www.domain2.com /var/www/virtual/big.server.com/htdocs

Всякий раз, когда у вас есть тег (, он же имя, он же ключ )для пар значений во входных данных, я считаю, что лучше всего сначала создать массив этого сопоставления(f[])ниже, а затем вы можете просто распечатать любые значения, которые вы хотите в любом порядке, в котором вы хотите, и в любых условиях, которые вы хотите, просто получая доступ к значениям массива по их тегам.

Например, используя любой POSIX awk:

$ cat tst.awk
(NR > 1) && ($1 == "server") { prt() }
{
    tag = $1
    sub(/[[:space:]]*[^[:space:]]+[[:space:]]+/,"")
    sub(/;$/,"")
    f[tag] = $0
}
END { prt() }

function prt() {
    print f["listen"], f["server_name"], f["root"]
    delete f
}

$ awk -f tst.awk file
80 domain1.com www.domain1.com html
80 domain2.com www.domain2.com /var/www/virtual/big.server.com/htdocs

Если вы застряли с awk, отличным от -POSIX, который не поддерживает классы символов, просто замените [:space:]на \t(это пустой символ, затем обратную косую черту, а затемt).

Существуют более короткие способы просто получить вывод по вашему конкретному вопросу, но описанный выше подход дает вам возможность тривиально печатать, тестировать, переупорядочивать, изменять и т. д. эти и любые другие поля, с которыми вы хотите что-то делать.