Как уменьшить изображение файла, созданного с помощью dd?

Использованиеawk:

awk '{ group[$2] = (group[$2] == "" ? $1 : group[$2] OFS $1 ) }
     END { for (group_name in group) print group_name, group[group_name] }' inputfile

Это сохраняет группы в массиве с именем group. Этот массив индексируется по имени группы (, второму столбцу входных данных ), и для каждой строки ввода из inputfileзначение в первом столбце добавляется к правильной группе.

Блок ENDперебирает все собранные группы и выводит имя группы и записи этой группы.

Эта awkпрограмма с более удобным расположением элементов:

{
    group[$2] = (group[$2] == "" ? $1 : group[$2] OFS $1 )
}

END {
    for (group_name in group)
        print group_name, group[group_name]
}

Обратите внимание, что это не то, что вы хотели бы сделать, если у вас есть огромные объемы данных, поскольку массив groupфактически будет хранить все входные данные, считанные из файла..

Для больших объемов данных мы предполагаем, что ввод отсортирован по именам групп (второй столбец )и используем

awk '$2 != group_name { if (group != "") print group_name, group; group = ""; group_name = $2 }
    { group = (group == "" ? $1 : group OFS $1) }
    END { if (group != "") print group_name, group }' inputfile

Это отслеживает, что представляет собой текущая группа, и собирает данные для этой группы. Всякий раз, когда второй столбец во входных данных переключается на другое значение, он выводит собранные групповые данные и начинает собирать новые данные. Это означает, что всегда сохраняется только несколько строк ввода, а не весь набор входных данных.

Эта последняя awkпрограмма с более красивым макетом:

$2 != group_name {
    if (group != "")
        print group_name, group

    group = ""
    group_name = $2
}

{
    group = (group == "" ? $1 : group OFS $1)
}

END {
    # Output last group (only), if there was any data at all.
    if (group != "")
        print group_name, group
}