Суммируйте большие числа и распечатайте результат со всеми десятичными знаками для указанного вопроса при использовании массивов awk.

Не принимая во внимание вашу проблему с большими числами, я бы написал awkпрограмму примерно так:

BEGIN {
        FS = "\\|~\\^"
        OFS= "|~^"
}

$1 == "H" {
        header = $0
}

$1 == "R" {
        name = $3
        sub("T.*", "", name)

        sum[name] += $4
        cnt[name] += 1

        if (cnt[name] == 1)
                print header >name ".txt"

        print >name ".txt"
}

$1 == "T" {
        for (name in sum)
                print $1, $2, cnt[name], $4, sum[name] >name ".txt"
}

Для удобства я установил разделитель полей вывода OFSна |~^. Это позволяет мне не беспокоиться о вставке его между полями, которые я вывожу. В качестве разделителя полей для ввода FSиспользуется регулярное выражение, соответствующее этой строке.

Затем у меня есть три основных блока кода:

1. Один для разбора строки H. Предполагается, что существует только один из них и что он возникает в начале. Это просто сохраняет строку заголовка в переменной header.

2. Один для разбора строк R. Каждая запись содержит дату, которая должна использоваться в качестве имени выходного файла в 3-м поле. Это анализируется так же, как и вы. Сумма за эту дату накапливается, а также увеличивается счетчик.

   Если счетчик равен единице, то есть если мы впервые видим эту конкретную дату, мы записываем заголовок в выходной файл, связанный с этой датой. Затем мы записываем текущую запись в файл.

3. Последний блок анализирует строку T. Предполагается, что есть только один из них и что он происходит в конце. Это просто выводит накопленные суммы и подсчеты для каждой отдельной даты в файл, связанный с этой датой, вместе с некоторыми данными из исходной строки T.

Для поддержки произвольно больших чисел (вы говорите в другом месте , что у вас есть числа, для хранения которых требуется более 100 бит, и поэтому целое число вawk)будет переполнено, мы используем калькулятор произвольной точности bcкак "сопроцесс" (своего рода вычислительная служба ). Строка с надписью sum[name] += $4заменена на

if (sum[name] == "") sum[name] = 0
printf "%s + %s\n", sum[name], $4 |& "bc"
"bc" |& getline sum[name]

Для этого требуется GNU awk(, доступный для большинства систем Unix, так или иначе ).

Это сначала инициализирует сумму для текущей даты нулем, если для этой даты еще нет суммы. Мы делаем это, потому что нам нужно поставить от 0до bcдля начальной суммы.

Затем мы печатаем выражение, которое bcдолжно вычислить, используя специальный |&конвейер GNUawk-для записи в сопроцесс. Утилита bc, которая будет запускаться и работать параллельно с нашим сценарием awk, выполняет вычисления, а следующая getlineсчитывает вывод из bcиз другого канала |&прямо в sum[name]..

Насколько я понимаю, GNU awkне будет порождать отдельный bcпроцесс для каждого суммирования, а будет поддерживать один bcпроцесс, работающий как сопроцесс. Таким образом, это будет медленнее, чем выполнение вычислений внутри awkизначально, но будет намного быстрее, чем создание отдельного bcдля каждого суммирования.

Для заданных данных будут созданы следующие два файла:

$ cat 2019-03-05.txt
H|~^20200425|~^abcd|~^sum
R|~^abc|~^2019-03-05T12:33:52.27|~^105603.042|~^2018-10-23T12:33:52.27|~^aus
R|~^abc|~^2019-03-05T12:33:52.27|~^2054.026|~^2018-10-24T12:33:52.27|~^usa
R|~^abc|~^2019-03-05T12:33:52.27|~^30.00|~^2018-08-05T12:33:52.27|~^ddd
R|~^abc|~^2019-03-05T12:33:52.27|~^20.00|~^2018-07-23T12:33:52.27|~^audg
T|~^20200425|~^4|~^xxx|~^107707.068

$ cat 2019-03-06.txt
H|~^20200425|~^abcd|~^sum
R|~^abc|~^2019-03-06T12:33:52.27|~^123562388.23456|~^2018-04-12T12:33:52.27|~^hhh
R|~^abc|~^2019-03-06T12:33:52.27|~^10.00|~^2018-09-11T12:33:52.27|~^virginia
R|~^abc|~^2019-03-06T12:33:52.27|~^15.03|~^2018-10-23T12:33:52.27|~^jjj
R|~^abc|~^2019-03-06T12:33:52.27|~^10.04|~^2018-04-08T12:33:52.27|~^jj
T|~^20200425|~^4|~^xxx|~^123562423.30456