Проблема в вашем коде,

awk 'BEGIN{min=9}{for(i=2;i<=2;i++){min=(min<$i)?min:$i}print min;exit}' file.dat

... заключается в том, что вы сразу exitпосле обработки первой строки ввода. Ваш средний блок должен запускаться для каждой строки . Затем в блоке ENDвы можете распечатать найденные значения. Вы делаете это в другом фрагменте кода:

awk '{if ($1 > max) max=$1}END{print max}'

Другая проблема заключается в том, что вы инициализируете minмагическим числом (9 в первом коде, который я цитировал, и 0 во втором фрагменте; переменные, не инициализированные явно, имеют значение 0, если вы используете их в вычислениях ). Если это магическое число не попадает в диапазон чисел в фактических данных, то рассчитанные минимальные и/или максимальные значения будут неверными. Лучше инициализировать как min, так и max некоторым значением, найденным в данных.

Чтобы отслеживать как минимальное, так и максимальное значения, вам нужны две переменные, и обе из них необходимо сверять с данными в файле для каждой строки, чтобы увидеть, нуждаются ли они в обновлении.

Поскольку awkподдерживает массивы, было бы естественно использовать массивы для minи maxс одним элементом массива на столбец. Это то, что я сделал в коде ниже.

Обобщается на любое количество столбцов:

NF == 0 {
        # Skip any line that does not have data
        next
}

!initialized {
        # Initialize the max and min for each column from the
        # data on the first line of input that has data.
        # Then immediately skip to next line.

        nf = NF

        for (i = 1; i <= nf; ++i)
                max[i] = min[i] = $i

        initialized = 1
        next
}

{
        # Loop over the columns to see if the max and/or min
        # values need updating.

        for (i = 1; i <= nf; ++i) {
                if (max[i] < $i) max[i] = $i
                if (min[i] > $i) min[i] = $i
        }
}

END {
        # Output max and min values for each column.

        for (i = 1; i <= nf; ++i)
                printf("Column %d: min=%s, max=%s\n", i, min[i], max[i])
}

Учитывая этот скрипт и данные в вопросе:

$ awk -f script.awk file
Column 1: min=0.0000, max=0.4916
Column 2: min=-24.1254, max=-23.4334

Условие NF == 0для первого блока (, которое выполняется для всех строк ), должно обеспечивать пропуск пустых строк. Тест означает "если нет полей (столбцов )данных в этой строке". Переменная initializedбудет равна нулю с самого начала (логически ложь ), но будет установлена ​​в единицу (логически истина ), как только первая строка с данными будет читать.

Переменная nfинициализируетсяNF(числом полей )в строке, из которой мы инициализируем значения minи max.Это сделано для того, чтобы вывод в блоке ENDработал, даже если в последней строке нет полей.