perl -F, -lane '
   exists $h{$F[0]} or $h[$h{$F[0]}=@h]=$_;
   $h=$_; /,false$/ or $_=$h for $h[$h{$F[0]}];
   END{ print for @h; }
' duplicates.file

Структуры данных:

• Хэш %h, чьи ключи являются первыми полями. (AAA, BBB, CCC и т. д. )и соответствующие значения являются числами, указывающими порядок, в котором встречались ключи. Таким образом, например, клавиша AAA => 0, клавиша BBB => 1, клавиша CCC => 2.
• Массив @h, элементами которого являются строки, содержащиеся в порядке печати. Таким образом, если в данных найдены и истина, и ложь, то в массив попадет ложное значение. OTW, если есть один тип данных, то он будет присутствовать.

Другой способ — использовать GNU sed:

sed -Ee '
   G
   /^([^,]*),(false|true)\n(.*\n)?\1,\2(\n|$)/ba
   /^([^,]*)(,true)\n(.*\n)?\1,false(\n|$)/ba
   /^([^,]*)(,false)\n((.*\n)?)\1,true(\n|$)/{
      s//\3\1\2\5/;h;ba
   }
   s/([^\n]*)\n(.*)$/\2\n\1/;s/^\n*//
   h;:a;$!d;g
' duplicates.file

FWIW, код, эквивалентный POSIX для приведенного выше кода GNU -sed, указан ниже:

sed -e '
   G

   /^\([^,]*\),\(false\)\n\(.*\n\)\{0,1\}\1,\2$/ba
   /^\([^,]*\),\(false\)\n\(.*\n\)\{0,1\}\1,\2\n/ba

   /^\([^,]*\),\(true\)\n\(.*\n\)\{0,1\}\1,\2$/ba
   /^\([^,]*\),\(true\)\n\(.*\n\)\{0,1\}\1,\2\n/ba

   /^\([^,]*\),true\n\(.*\n\)\{0,1\}\1,false$/ba
   /^\([^,]*\),true\n\(.*\n\)\{0,1\}\1,false\n/ba

   /^\([^,]*\)\(,false\)\n\(\(.*\n\)\{0,1\}\)\1,true$/{
      s//\3\1\2/
      h
      ba
   }
   /^\([^,]*\)\(,false\)\n\(\(.*\n\)\{0,1\}\)\1,true\n/{
      s//\3\1\2\n/
      h
      ba
   }

   y/\n_/_\n/
   s/\([^_]*\)_\(.*\)$/\2_\1/;s/^_*//
   y/\n_/_\n/

   h;:a;$!d;g
' duplicates.file

Пояснение

• В этом методе мы сохраняем результат, который будет окончательно напечатан, в ячейке удержания.
• Для каждой прочитанной строки мы добавляем пространство удержания к пространству шаблонов для проверки текущей строки относительно -и -относительно существующего состояния пространства удержания.
• Во время этого сравнения могут произойти 5 вещей :
  • a )Текущая строка где-то совпадает с линией удержания и ложь :ложь.
    • [ДЕЙСТВИЕ] Поскольку обнаружено такое же ложное состояние, ничего не делать.
  • b )Текущая строка где-то совпадает с линией удержания и true :true.
    • [ДЕЙСТВИЕ] Поскольку найдено такое же истинное состояние, ничего не делать.
  • c )Текущая строка где-то совпадает с линией удержания и true :false.
    • [ДЕЙСТВИЕ] Поскольку ложное состояние уже существует, ничего не делайте.
  • d )Текущая строка совпадает где-то в строке удержания и false :true.
    • [ДЕЙСТВИЕ] Это требует некоторой работы, поскольку нам нужно заменить ложную строку в той же самой позиции, где находится истинная.
  • e )Текущая строка НЕ ​​СООТВЕТСТВУЕТ нигде в линии удержания.
    • [ДЕЙСТВИЕ] Переместить текущую строку в конец.

Результаты

AA,false
BB,false
CC,false
DD,true