Отключение CNA в MacOS

Если вы просто хотите взять список шаблонов и набор файлов и распечатать имена всех файлов, которые соответствуют каждому шаблону в определенном столбце, все, что вам нужно, это GNU awk (по умолчанию в Linux):

awk -F';' '{
                if(NR==FNR){ 
                    p[$0]++; 
                    next
                } 
                if($3 in p){
                    printf "%s found in %s\n", $3,FILENAME; 
                    nextfile
                }
            }' patterns file1.csv file2.csv fileN.csv

Объяснение

• awk -F ';' : установите разделитель полей на ; .
• if (NR == FNR) {p [$ 0] ++; next} : NR - номер текущей строки ввода, а FNR - строка текущего файла количество. Они равны только тогда, когда обрабатывается первый файл. Таким образом, это сохранит каждую строку файла шаблонов (1-й файл) в массиве p и перейдет к следующей строке. Он будет запущен только для файла шаблонов.
• if ($ 3 в p) {printf "% s найдено в% s \ n", $ 3, FILENAME; nextfile : Теперь мы смотрим на файлы csv. если третье поле является одним из элементов массива p (если оно было в файле шаблонов), выведите третье поле (шаблон) и имя файла, в котором он был найден. Затем перейдите к следующий файл. Переменная FILENAME содержит путь к текущему файлу, который обрабатывается. nextfile является функцией gawk и делает то, что написано на банке: он переходит к следующему файлу для обработки.

Например, для этих файлов:

$ cat patterns 
foo
bar
baz

$ cat file1.csv 
blah;blah;foo;blah
blah;blah;foo;blah
blah;blah;foo;blah

$ cat file2.csv 
blah;blah;bar;blah

$ cat file3.csv 
blah;blah;baz;blah

Вы получите следующий результат:

$ awk -F';' '{if(NR==FNR){p[$0]++; next} if($3 in p){printf "%s found in %s\n", $3,FILENAME; nextfile}}' patterns file*csv 
foo found in file1.csv
bar found in file2.csv
baz found in file3.csv

Если вы можете иметь каждый шаблон в нескольких файлах, вы можете использовать немного другой подход:

awk -F';' '{
            if(NR==FNR){ 
                p[$0]++; 
                next
            } 
            if($3 in p && !seen[FILENAME][$3]){
                printf "%s found in %s\n", $3,FILENAME; 
                seen[FILENAME][$3]++
            }
        }' patterns file1.csv file2.csv fileN.csv

На этот раз нет nextfile , поскольку нам нужно обработать весь файл, и есть счетчик, который увеличивается каждый раз, когда в данном файле обнаруживается шаблон, поэтому мы не сообщаем один и тот же шаблон несколько раз.

Итак, изменив file1.csv ​​выше на:

$ cat file1.csv 
blah;blah;foo;blah
blah;blah;baz;blah
blah;blah;bar;blah
blah;blah;foo;blah

Мы получим:

$ awk -F';' '{if(NR==FNR){p[$0]++; next} if($3 in p && !seen[FILENAME][$3]){printf "%s found in %s\n", $3,FILENAME; seen[FILENAME][$3]++}}' patterns file*csv 
foo found in file1.csv
baz found in file1.csv
bar found in file1.csv
bar found in file2.csv
baz found in file3.csv

Если это слишком медленно, как это может быть для больших файлов, вы можете изменить его, чтобы он останавливался чтение файла, если в нем уже найдены все шаблоны:

awk -F';' '{
            if(NR==FNR){ 
                p[$0]++; 
                next
            } 
            if($3 in p && !seen[FILENAME][$3]){
                printf "%s found in %s\n", $3,FILENAME; 
                seen[FILENAME][$3]++
            }
            if( length(seen[FILENAME]) == length(p) ){
                nextfile
            }
           }' patterns file1.csv file2.csv fileN.csv