Убивать другие процессы в конвейере (программно)

В:

cmd1 | cmd2

cmd2не умирает автоматически, когда cmd1завершает работу, однако он увидит конец -файла -на своем стандартном вводе. И вот так трубопроводы обычно заканчиваются.

В:

echo foo | sed s/o/e/g

sedпрекратит работу после того, как echoзавершится, потому что он обнаружит, что больше нечего читать из его стандартного ввода.

Вы можете попытаться cmd1убить cmd2после завершения, но что, если cmd2еще не прочитал все, что cmd1написал в канал?

Если cmd2умирает первым, cmd1не умирает автоматически, но он будет уничтожен (с помощью SIGPIPE )при следующей попытке записи в (теперь сломанный )канал.

Вот такие конвейеры:

yes | head

terminate(yesуничтожается при первой записи в канал после завершения headпосле чтения и печати первых 10 строк ).

Теперь, если вы действительно хотите убить процессы на другом конце канала, нет переносимого способа узнать, какой процесс (es )имеет файловый дескриптор на другом конце канала.

В Linux вы можете искать файлы в /proc/*/fd, которые имеют тот же индекс, что и канал на fd до вашего конца канала, и где разрешения самой символической ссылки указывают, какой конец канала это.

$ (ls -lLi /proc/self/fd/3; ls -l /proc/self/fd/3) 3>&1 >&2 | (ls -Lil /proc/self/fd/0; ls -l /proc/self/fd/0)
224052 prw------- 1 chazelas chazelas 0 Sep 20 23:26 /proc/self/fd/3|
224052 prw------- 1 chazelas chazelas 0 Sep 20 23:26 /proc/self/fd/0|
l-wx------ 1 chazelas chazelas 64 Sep 20 23:26 /proc/self/fd/3 -> pipe:[224052]
lr-x------ 1 chazelas chazelas 64 Sep 20 23:26 /proc/self/fd/0 -> pipe:[224052]

Один и тот же индекс канала, и fd на стороне записи имеет разрешения w, а на стороне чтения — права r.

Например,с помощью zshвы можете получить pid процессов, у которых есть fd на считывающем конце канала, другой конец которого находится на нашем fd 3 с помощью:

pids=(/proc/<->/fd/*(Nf{u+r}e{'[[ $REPLY -ef /dev/fd/3 ]]'}-p:h:h:t))
pids=(${(u)pids}) # unique

Пример:

$ (pids=(/proc/<->/fd/*(Nf{u+r}e{'[[ $REPLY -ef /dev/fd/3 ]]'}-p:h:h:t))
  pids=(${(u)pids}); ps -fp $pids) 3>&1 >&2 | tr a b
UID        PID  PPID  C STIME TTY          TIME CMD
chazelas 24157 11759  0 23:41 pts/1    00:00:00 tr a b

Так что вы могли бы сделать (по-прежнему в Linux и сzsh):

run_and_kill_the_other_end() {
  setopt localoptions localtraps
  trap : TERM
  "$@"
  local ret=$?
  local -aU pids
  if [ -p /dev/stdout ]; then
    pids=(/proc/<2->/fd/<0-9>(Nf{u+r}e{'[[ $REPLY -ef /dev/stdout ]]'}-p:h:h:t))
    exec >&- # give the right end a chance to see eof and act upon it
  fi
  [ -p /dev/stdin ] &&
    pids+=(/proc/<2->/fd/<0-9>(Nf{u+w}e{'[[ $REPLY -ef /dev/stdin ]]'}-p:h:h:t))
  (($#pids)) && kill $pids 2> /dev/null
  return $ret
}

А потом:

run_and_kill_the_other_end node a.js | run_and_kill_the_other_end node b.js

Хотя опять же, это, вероятно, не то, что вы хотите делать. Например:

$ run_and_kill_the_other_end seq 100 |
    run_and_kill_the_other_end sort |
    run_and_kill_the_other_end wc -l
0

sortбыл убит до того, как успел записать свой отсортированный вывод. wc -lудалось бежать.

В качестве льготного периода можно указать задержку, но какой продолжительности она должна быть? Например, если я добавлю sleep 0.1после exec >&-, я увижу:

$ run_and_kill_the_other_end seq 100 | run_and_kill_the_other_end sort | run_and_kill_the_other_end wc -l
100
$ run_and_kill_the_other_end seq 10000 | run_and_kill_the_other_end sort | run_and_kill_the_other_end wc -l
10000
$ run_and_kill_the_other_end seq 100000 | run_and_kill_the_other_end sort | run_and_kill_the_other_end wc -l
0

Это также означает безоговорочную отсрочку закрытия конвейера. Вы можете улучшить это, используя вместо этого zshzselectс тайм-аутом.