Как искать текущее слово на всех открытых вкладках в Vim?

Это - на самом деле поведение по умолчанию, хотя может быть трудно заметить: попробовать * затем изменитесь на другую вкладку и использование n ответ N в командном режиме для перехода вперед и назад между поисковыми хитами.

Это может иметь больше смысла сначала при включении выделения для всех хитов:

:set hlsearch

 :bufdo vimgrepadd yoursearchterm % | copen

Поскольку я делал часто это, я смял (improvable) сценарий.

Вы или кто-то еще могли бы найти это полезным.

Короткое объяснение:

В основном это ищет буферный список и выставочный результат в quickfix-окне.

Две основных команды добавляется.

1. Поиск <образец> : Искать все буферы <образец> .
2. Search1 <образец> : Искать все буферы <образец> , но только показать первый результат для каждого буфера. Обычно полезный для списка всех буферов, где функция, переменная нечто используется, (или что когда-либо).

удар Использования (: Искать! нечто ) для добавления к результатам.

Дополнительно GSearch и GSearch1 добавляется, где различие - то, что с Поиск сценарий добавляет regex разделитель, например:

foo -> /foo/

, Где как GSearch ожидают, что это будет включено.

флаг j всегда добавляется для предотвращения перехода.

Код:

существуют некоторые взломы для предотвращения списка ошибок, одновременно сохраняя код коротким. попытка / выгода была немного громоздкой на bufdo.

let s:not_idents = split("/!#$%&\"`´¨'¯()*+,-.:;<=>?¿@[\]^{|}µ¶·¸~±×÷®©«»¬­ª°º¹²³¼½¾", '\zs')
" Create a delimited pattern. "
fun! s:Parse_pat(pat)
    for c in s:not_idents
        if stridx(a:pat, c) == -1
            return c . a:pat . c
        endif
    endfor
    echohl Error
    echom "Could not delimit pattern '". a:pat ."'"
    echohl None
    return ''
endfun

fun! s:AllBufSearch(pat, bang, uno, isg)
    if a:isg
        let pat = a:pat
    else
        let pat = s:Parse_pat(a:pat)
    endif
    if pat == ''
        return
    endif
    cclose
    let [_buf, _view] = [bufnr("%"), winsaveview()]
    let _foldenable = &foldenable
    set nofoldenable

    " Copy of current qflist. "
    let qfc = getqflist()
    " Hack to prevent error if no matches. "
    call setqflist([{}])
    silent execute "bufdo vimgrepadd! " . pat . "j %"
    " Restore "
    exec "buffer " . _buf
    let &foldenable = _foldenable
    call winrestview(_view)
    " Fix "
    let qf = getqflist()
    call remove(qf, 0)
    " Only one listing per buffer. "
    if a:uno
        let bn = {}
        let i  = 0
        for m in qf
            if has_key(bn, m["bufnr"])
                call remove(qf, i)
            else
                let bn[m["bufnr"]] = 1
                call remove(qf[i], "valid")
                let i += 1
            endif
        endfor
    endif
    if a:bang == "!"
        let qf = qfc + qf
    endif
    " If any matches, copen. "
    if len(qf)
        call setqflist(qf)
        copen
    endif
endfun

command! -nargs=1 -bang Search   call s:AllBufSearch(<q-args>, "<bang>", 0, 0)
command! -nargs=1 -bang Search1  call s:AllBufSearch(<q-args>, "<bang>", 1, 0)
command! -nargs=1 -bang GSearch  call s:AllBufSearch(<q-args>, "<bang>", 0, 1)
command! -nargs=1 -bang GSearch1 call s:AllBufSearch(<q-args>, "<bang>", 1, 1)