sed удаляет строки, начинающиеся с #, но не с #! (shell скрипты)

sed -i -e '/^#!/p' -e '/^#/d' file

Это будет проходить через файл построчно и находит строку, начинающуюся с #! будет напечатано первым выражением. Затем он будет удален из пространства шаблонов вторым выражением (т. е. он не будет напечатан через секундураз командой по умолчанию p, которая действует, когда не используется sed -n).

Строка, начинающаяся только с #, будет игнорироваться первым выражением, но удаляться вторым выражением.

Любая другая строка будет напечатана командой по умолчанию p.

Чтобы разрешить пробелы перед #(а также удалить эти строки):

sed -i -e '/^[[:blank:]]*#!/p' -e '/^[[:blank:]]*#/d' file

Выражение [[:blank:]]будет соответствовать пробелу или табуляции. персонаж.

Как упомянул Стефан, это комментарии, изменение pна bв первом выражении позволит сценарию sedпродолжить работу со следующей строкой ввода без учета второе выражение, если первое выражение совпадает. Команда bпереходит к предопределенной метке или к концу сценария sed, если метка не указана. Это будет оптимизация.

Для "и"двух адресов нужна группа команд ({...;}):

sed '/^[[:space:]]*#/{/^#!/!d;}' < file

С GNU sed, вы можете использовать -iвместо inplace, замените [[:space:]]на \s(при условии, что это последняя версия) и опустите ;:

sed -i '/^\s*#/{/^#!/!d}' file

Вы можете вложить несколько, но имейте в виду, что при переносе у вас не может быть ничего после }. Таким образом, для A и B, а не C и не Dэто будет:

sed '/A/{/B/{/C/!{/D/!d;}' -e '}' -e '}' < file

Или:

sed '
  /A/{
    /B/{
      /C/!{
        /D/!d
      }
    }
  }' < file

Вывод: удалить все комментарии, не относящиеся к шебангу.

sed -e '1{/^\s*\#/{/^\#!/!d}}' -e '1!{/^\s*\#/d}' file

Ваша команда изменена для использования одинарных кавычек (без двойных \\):

sed '/^\(\s\)*\#/d'

будет работать почти правильно, просто добавив деталь, что (после #) должно быть что-то, что не является звездочкой [^!]sed '/^\(\s\)*\#[^!]/d'. Но это не удастся с пустой строкой после символа комментария (#`).

Для этого нужно утверждать, что линия закончилась ($).

Для этого нам потребуется использование расширенного синтаксиса ([^!]|$):

sed -E '/^\s*\#([^!]|$)/d'

Или, более переносимого:

sed -E '/^[ \t]*\#([^!]|$)/d'

Однако для сценария только первая строка, которая начните как #! имеет значение.
Все остальные строки, начинающиеся с необязательного пробела и #, являются комментариями:

sed -e '1{/^#!/!d}' -e '1!{/^[ \t]*#/d}' file

Что означает:

Первая -e

, если первая строка начинается с комментария (пробел и #), но не начинается точно с участием #! он стирается.

Вторая -e

другие строки (1! ), начинающиеся с необязательного пробела и #, удаляются.

Используйте негативный взгляд -вперед в Perl:

perl -ne 'print unless /#(?!!)/'

Это удаляет строки, содержащие #, за которыми не следует !. Если вы хотите сопоставить #только в начале строки, возможно, с предшествующим пробелом, используйте

perl -ne 'print unless /^\s*#(?!!)/'

sed -i -e '/^\s*#\([^!]\|$\)/d'

Где:

• ^начало строки
• \s*ноль или более пробелов
• #одна решетка
• \([^!]\|$\)с последующим символом, который не является !или конец строки.

Мне помогло:

$ cat test.sed 
  # delete this one

  #! don't delete this one

        # delete this too

Команда:

$ sed -i -e '/^[[:space:]]*#[^!].*/d' test.sed

Результат:

$ cat test.sed 

  #! don't delete this one

Что ж, эта команда не удалит строк только с одиноким #. Итак, я сохраняю этот ответ, чтобы показать, почему вам нужно ссылаться на другие решения.

Предположительно, вы хотите удалить все строки комментариев, (начинающиеся с любого количества пробелов, за которыми следует #), кроме челки -, которая должна находиться в первой строке для обнаружения..

Вы можете использовать ту же самую команду подстановки, если вы ограничите ее рассмотрением только всего, начиная со строки 2; в нотации sedэто диапазон 2,$. Вы ограничиваете команды sedдиапазоном, добавляя к ним префикс этого диапазона :

sed "2,${/^\(\\s\)*\\#/d}"

или с кавычками оболочки, которые позволяют использовать более читаемые обратные пробелы и без ненужной группировки регулярных выражений:

sed -e '2,${/^\s*#/d}'

Пример

Вход:

#!/path/to/a/shebang-command
# This is the first comment

command 1
  # another comment
  command 2
# Final comment

Выход:

#!/path/to/a/shebang-command

command 1
  command 2