Некоторые специальные файлы в Unix

has_all_iregexps() {
  awk '
    BEGIN {
      if (ARGC <= 1) exit
      for (i = 1; i < ARGC; i++) s[tolower(ARGV[i])]
      n = ARGC - 1
      ARGC = 1
    }
    {
      for (i in s) if (tolower($0) ~ i) {
        delete s[i]; if (!--n) exit
      }
    }
    END {
      if (n) {
        print "Those regexps were not matched:"
        for (i in s) print "  " i
        exit(1)
      }
    }' "$@" >&2
}

А затем:

nginx -V 2>&1 |
  has_all_iregexps 'nginx/1\.9\.10' \
                   'ngx_pagespeed-release-1\.9\.32\.10' \
                   'openssl-1\.0\.2f' \
                   'modsecurity-2\.9\.‌​0' &&
  echo "has the stuff we need"

Или:

has_all_istrings() {
  awk '
    BEGIN {
      if (ARGC <= 1) exit
      for (i = 1; i < ARGC; i++) s[tolower(ARGV[i])]
      n = ARGC - 1
      ARGC = 1
    }
    {
      for (i in s) if (index(tolower($0), i)) {
        delete s[i]; if (!--n) exit
      }
    }
    END {
      if (n) {
        print "Those strings were not found:"
        for (i in s) print "  " i
        exit(1)
      }
    }' "$@" >&2
}

nginx -V 2>&1 |
  has_all_istrings 'nginx/1.9.10' \
                   'ngx_pagespeed-release-1.9.32.10' \
                   'openssl-1.0.2f' \
                   'modsecurity-2.9.‌​0' &&
  echo "has the stuff we need"

(tolower- для нечувствительного к регистру сопоставления, чтобы соответствовать вашему использованию -i, хотя я не уверен, почему вы хотите сделать нечувствительное к регистру сопоставление здесь).