Una gran herramienta para el procesamiento de texto es awk . El siguiente ejemplo utiliza awk estándar simple en FreeBSD 11.1. @RomanPerekhrest tiene una solución elegante en otra respuesta si prefiere GNU awk.

Su entrada está separada por comas -. Por eso invocamos awkcon el parámetro -F,.

Luego podemos imprimir columnas usando la declaración print. $1es la primera columna. $2es la segunda columna.

$ awk -F, '{ print $8 }' inputfile.csv
2017-1-5 1:07:09
2017-11-25 19:57:17

Esto nos da la octava columna para cada fila.

Este es entonces el campo de fecha que desea manipular. En lugar de configurar el delimitador usando el parámetro de línea de comando -, podemos hacerlo como parte del script. FS para el delimitador de entrada y OFS para el delimitador de salida.

$ awk 'BEGIN { FS = "," } ; { print $8 }' inputfile.csv
2017-1-5 1:07:09
2017-11-25 19:57:17

Cuando trabajo con fechas, a menudo prefiero usar la utilidad datepara asegurarme de manejarlas correctamente. Y no necesito preocuparme si estoy usando GNU awk o regular. Además, obtengo una gran falla si la fecha no se analiza correctamente.

Los parámetros interesantes son:

-j     Specify we do not want to set the date at all
-f     The format string we use for input
+      The format string we use for output

Entonces, si ejecutamos esto para una fecha:

$ date -j -f "%Y-%m-%d %H:%M:%S" +"%Y-%m-%d %H:%M:%S" "2017-1-5 1:07:09"
2017-01-05 01:07:09

Entonces podemos combinar esto con awk. Observe cómo se escapan las comillas. Este es probablemente el mayor obstáculo para un principiante.

$ awk -F, '{ system("date -j -f \"%Y-%m-%d %H:%M:%S\" +\"%Y-%m-%d %H:%M:%S\" \""$8"\"")}' inputfile.csv
2017-01-05 01:07:09
2017-11-25 19:57:17

La llamada al sistema parece correcta -pero, lamentablemente, solo nos permite capturar el código de retorno y se imprime directamente en la salida. Para evitar esto usamos el patrón cmd | getline. El siguiente ejemplo simple leerá la fecha actual en mydate:

$ awk 'BEGIN { cmd = "date"; cmd | getline mydate; close(cmd); print mydate }'
Thu Mar  1 16:26:15 CET 2018

Usamos la palabra clave BEGINya que no tenemos información para este ejemplo simple.

Así que ampliemos esto:

awk 'BEGIN { FS=","; OFS=FS };
     { 
         cmd = "date -j -f \"%Y-%m-%d %H:%M:%S\" +\"%Y-%m-%d %H:%M:%S\" \""$8"\"";
         cmd | getline firstdate;
         close(cmd);
         cmd = "date -j -f \"%Y-%m-%d %H:%M:%S\" +\"%Y-%m-%d %H:%M:%S\" \""$9"\"";
         cmd | getline seconddate;
         close(cmd);
         print $1,$2,$3,$4,$5,$6,$7,firstdate,seconddate
     }' inputfile.csv

Y podemos reducirlo a una -línea:

awk 'BEGIN {FS=",";OFS=FS};{cmd="date -j -f \"%Y-%m-%d %H:%M:%S\" +\"%Y-%m-%d %H:%M:%S\" \""$8"\"";cmd | getline firstdate;close(cmd);cmd="date -j -f \"%Y-%m-%d %H:%M:%S\" +\"%Y-%m-%d %H:%M:%S\" \""$9"\"";cmd | getline seconddate;close(cmd);print $1,$2,$3,$4,$5,$6,$7,firstdate,seconddate}' inputfile.csv

Lo que me da la salida:

1111,2222,3333,4444,5555,6666,7777,2017-01-05 01:07:09,2017-01-05 01:11:53
1111,2222,3333,4444,5555,6666,7777,2017-11-25 19:57:17,2017-11-25 19:58:54

Apéndice

Como el propósito aquí es aprender un buen hábito, mejor actualizo esta respuesta. Es un mal hábito repetir código.Cuando comience a hacer eso, debe dividir las cosas en una función. Como notará, el código a continuación se vuelve inmediatamente más legible.

awk 'function convertdate(the_date) {
         cmd = "date -j -f \"%Y-%m-%d %H:%M:%S\" +\"%Y-%m-%d %H:%M:%S\" \""the_date"\"";
         cmd | getline formatted_date;
         close(cmd);
         return formatted_date
     }
     BEGIN { FS=","; OFS=FS };
     { 
         print $1,$2,$3,$4,$5,$6,$7,convertdate($8),convertdate($9)
     }' inputfile.csv

Acostúmbrate a esto y notarás cuánto más fácil será introducir el manejo de errores más adelante.