Хочу заменить только первым вхождением с sed

Вот еще два программных усилия с помощью sed: оба они читают весь файл в одну строку, затем поиск заменяет только первый.

sed -n ':a;N;$bb;ba;:b;s/\(claudi\)o/\1a/;p' file
sed -n '1h;1!H;${g;s/\(claudi\)o/\1a/;p;}' file

С комментарием:

sed -n '                # don't implicitly print input
  :a                    # label "a"
  N                     # append next line to pattern space
  $bb                   # at the last line, goto "b"
  ba                    # goto "a"
  :b                    # label "b"
  s/\(claudi\)o/\1a/    # replace
  p                     # and print
' file

sed -n '                # don't implicitly print input
  1h                    # put line 1 in the hold space
  1!H                   # for subsequent lines, append to hold space
  ${                    # on the last line
    g                     # put the hold space in pattern space
    s/\(claudi\)o/\1a/    # replace
    p                     # print
  }
' file

Вы можете использовать awk с флагом, чтобы знать, была ли замена уже сделана. Если нет, продолжить:

$ awk '!f && /claudio/ {$0="claudia"; f=1}1' file
claudia
antonio
claudio
michele

На самом деле действительно просто, если вы просто настроите небольшую задержку - нет необходимости дойти до ненадежных расширений:

sed '$H;x;1,/claudio/s/claudio/claudia/;1d' <<\IN
claudio
antonio
claudio
michele
IN

, которые просто дефицит Первая строка до второго и второй на третий и т. Д.

Это печатает:

claudia
antonio
claudio
michele

И еще один вариант

sed --in-place=*.bak -e "1 h;1! H;\$! d;$ {g;s/claudio/claudia/;}" -- nomi

Преимущество в том, что он использует двойные кавычки, так что вы можете использовать переменные внутри, т.е.

export chngFrom=claudio
export chngTo=claudia
sed --in-place=*.bak -e "1 h;1! H;\$! d;$ {g;s/${chngFrom}/${chngTo}/;}" -- nomi

Это также можно сделать без удерживаемого пространства и без объединения всех строк в пространство шаблона:

sed -n '/claudio/{s/o/a/;bx};p;b;:x;p;n;bx' nomi

Объяснение: Мы пытаемся найти "claudio", и если мы это делаем, мы переходим в небольшой цикл загрузки-печати между : x и bx . В противном случае печатаем и перезапускаем скрипт со следующей строки.

sed -n '      # do not print lines by default
  /claudio/ { # on lines that match "claudio" do ...
    s/o/a/    # replace "o" with "a"
    bx        # goto label x
  }           # end of do block
  p           # print the pattern space
  b           # go to the end of the script, continue with next line
  :x          # the label x for goto commands
  p           # print the pattern space
  n           # load the next line in the pattern space (clearing old contents)
  bx          # goto the label x
  ' nomi

sed -n '/claudia/{p;Q}'

sed -n '           # don't print input
    /claudia/      # regex search
    {              # when match is found do
    p;             # print line
    Q              # quit sed, don't print last buffered line
    {              # end do block

Резюме

Синтаксис GNU:

sed '/claudio/{s//claudia/;:p;n;bp}' file

Или даже (использовать только один раз заменяемое слово:

sed '/\(claudi\)o/{s//\1a/;:p;n;bp}' file

Или, в синтаксисе POSIX:

sed -e '/claudio/{s//claudia/;:p' -e 'n;bp' -e '}' file

работает с любым sed, обрабатывает только столько строк, сколько необходимо, чтобы найти первую claudio, работает, даже если claudioнаходится в первой строке и короче, поскольку использует только одну строку регулярного выражения.

Деталь

Чтобы изменить только одну строку, необходимо выбрать только одну строку.

Используя1,/claudio/(из вашего вопроса ), выберите:

• с первой строки (безусловно)
• на следующую строку, содержащую строку claudio.

$ cat file
claudio 1
antonio 2
claudio 3
michele 4

$ sed -n '1,/claudio/{p}' file
claudio 1
antonio 2
claudio 3

Чтобы выбрать любую строку , содержащую claudio, используйте :

$ sed -n `/claudio/{p}` file
claudio 1
claudio 3

И чтобы выбрать только первыйclaudioв файле, используйте:

sed -n '/claudio/{p;q}' file
claudio 1

Затем вы можете сделать замену только в этой строке:

sed '/claudio/{s/claudio/claudia/;q}' file
claudia 1

Это изменит только первое вхождение совпадения с регулярным выражением в строке, даже если их может быть более одного, в первой строке, совпадающей с регулярным выражением.

Конечно, регулярное выражение /claudio/можно упростить до:

$ sed '/claudio/{s//claudia/;q}' file
claudia 1

И тогда единственное, чего не хватает, это напечатать все остальные строки без -измененных:

sed '/claudio/{s//claudia/;:p;n;bp}' file

Новая версия GNU sedподдерживает опцию -z.

Normally, sed reads a line by reading a string of characters up to the end-of-line character (new line or carriage return).
The GNU version of sed added a feature in version 4.2.2 to use the "NULL" character instead. This can be useful if you have files that use the NULL as a record separator. Some GNU utilities can generate output that uses a NULL instead a new line, such as "find. -print0" or "grep -lZ".

Вы можете использовать эту опцию, если хотите, чтобы sedработало над разными строками.

echo 'claudio
antonio
claudio
michele' | sed -z 's/claudio/claudia/'

возвращает

claudia
antonio
claudio
michele

Сначала направить некоторый вывод в awk

Затем вы можете использовать переменные awk для замены

cat someFile | awk '!x{x=sub("wordToReplace","wordThatIsReplaced")}1'

Обратите внимание на номер в конце.

Требуется, но может быть любым числом, я выбрал 1 для обозначения первого экземпляра.