Grub запускается в командной строке после обновления BIOS и не может загрузить ни одну ОС

Вы можете сделать это с помощью zshвстроенных операторов glob. Это имело бы несколько преимуществ:

• легко решить эту проблему
• работать с путями, содержащими символы новой строки
• упростить выделение паттерна только в базовом имени
• работать с подстановочными знаками (в вашем подходе, findи grepинтерпретировать шаблон по-разному)
• получить отсортированный список
• работают даже на не -системах GNU (-printf, -iname, --colorне являются -стандартными расширениями ).

Может быть, что-то вроде:

#! /bin/zsh -
pattern="(#i)${1?Please specify a pattern}"

set -o extendedglob

typeset -A find_file_color
find_file_color=(
  dirname  $'\e[0;33;49m'
  basename $'\e[1;34;49m'
  match    $'\e[1;33;44m'
  reset    $'\e[m'
)

colorize_file() {
  local file=${1-$REPLY}
  case $file in
    (*/*)
      REPLY=$find_file_color[dirname]$file:h$find_file_color[reset]/;;
    (*)
      REPLY=
  esac
  REPLY+=$find_file_color[basename]${${file:t}//(#m)$~pattern/$find_file_color[match]$MATCH$find_file_color[basename]}$find_file_color[reset]
}

print -rC1 -- **/*$~pattern*(ND.+colorize_file)

Обратите внимание, что он строит и сортирует весь список перед передачей в printдля печати. Таким образом, вы начнете получать некоторый вывод только после того, как все файлы будут найдены. Чтобы распечатать их по мере их нахождения (, но тогда нам пришлось бы отказаться от сортировки ), вместо этого вы могли бы использовать функцию квалификатора glob для печати раскрашенного файла:

#! /bin/zsh -
pattern="(#i)${1?Please specify a pattern}"

set -o extendedglob

typeset -A find_file_color
find_file_color=(
  dirname  $'\e[0;33;49m'
  basename $'\e[1;34;49m'
  match    $'\e[1;33;44m'
  reset    $'\e[m'
)

colorize_file() {
  local file=${1-$REPLY}
  case $file in
    (*/*)
      REPLY=$find_file_color[dirname]$file:h$find_file_color[reset]/;;
    (*)
      REPLY=
  esac
  REPLY+=$find_file_color[basename]${${file:t}//(#m)$~pattern/$find_file_color[match]$MATCH$find_file_color[basename]}$find_file_color[reset]
  print -r -- $REPLY
  false # don't bother adding the file to the glob expansion
}

: **/*$~pattern*(ND.+colorize_file)